3.1 Welk deel van de arbeidsovereenkomsten is voor bepaalde tijd?

Concepten

• Arbeidsovereenkomst bepaalde tijd
• Arbeidsovereenkomst onbepaalde tijd
• Onverplaatsbaar artefact
• Vestiging
• Vestigingsnummer
• Werkovereenkomst afspraak
• Zorgkantoor regio

Relaties

• deel van
• gaat over
• geïdentificeerd door
• heeft deel
• heeft lokaliseerbaar gebied
• opereert in regio
• vestiging van

Eigenschappen

• einddatum
• heeft datawaarde
• startdatum

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: Zorgkantoren 3.1
2# Parameters: ?peildatum, ?zorgkantoor
3# Ontologie: versie 3.0 of nieuwer
4
5PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
6PREFIX onz-g: <http://purl.org/ozo/onz-g#>
7PREFIX onz-org: <http://purl.org/ozo/onz-org#>
8PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
9PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
10
11SELECT  (?vestiging AS ?Indeling)
12    (COUNT(DISTINCT ?overeenkomst_bepaald) AS ?Aantal_arbeidsovereenkomsten_bepaalde_tijd)
13    (COUNT(DISTINCT ?overeenkomst_bepaald) + COUNT(DISTINCT ?overeenkomst_onbepaald) AS ?Aantal_arbeidsovereenkomsten_voor_bepaalde_en_onbepaalde_tijd)
14    (100*?Aantal_arbeidsovereenkomsten_bepaalde_tijd/(?Aantal_arbeidsovereenkomsten_voor_bepaalde_en_onbepaalde_tijd) AS ?Percentage_bepaalde_tijd)
15
16WHERE {     
17    # definieer parameters
18    #BIND("2023-09-12"^^xsd:date AS ?peildatum)
19    # BIND(onz-org:ZorgkantoorMenzis AS ?zorgkantoor)
20
21    # selecteer personen met arbeidsovereenkomst (on)bepaalde tijd
22    VALUES ?type_overeenkomst {onz-pers:ArbeidsOvereenkomstBepaaldeTijd onz-pers:ArbeidsOvereenkomstOnbepaaldeTijd}
23    ?overeenkomst 
24        a ?type_overeenkomst ;
25        onz-g:hasPart ?overeenkomst_afspraak .
26    ?overeenkomst_afspraak
27        a onz-pers:WerkOvereenkomstAfspraak ;
28        onz-g:startDatum ?start_afspraak .
29    OPTIONAL { ?overeenkomst_afspraak onz-g:eindDatum ?eind_afspraak }
30    FILTER(?start_afspraak <= ?peildatum && ((?eind_afspraak >= ?peildatum) || (!BOUND(?eind_afspraak))))
31
32    ?overeenkomst_afspraak onz-g:isAbout ?locatie .
33    ?locatie a onz-g:StationaryArtifact ;
34        onz-g:partOf* ?vestiging_uri .
35    ?vestiging_uri a onz-org:Vestiging ;
36        onz-g:hasLocalizableArea/onz-g:identifiedBy/onz-g:hasPart/onz-g:hasPart ?postcode_6 .
37    BIND(IRI(SUBSTR(STR(?postcode_6), 1, STRLEN(STR(?postcode_6)) - 2)) AS ?postcode)
38    ?pc_gebied 
39        onz-g:identifiedBy ?postcode ;
40        onz-g:partOf+ ?zk_regio .
41    ?zk_regio a onz-org:ZorgkantoorRegio .
42    ?zorgkantoor onz-g:hasOperatingRange ?zk_regio .
43    
44    {     
45        ?vestiging_uri onz-g:identifiedBy ?vest_nr .    	
46        ?vest_nr a onz-org:Vestigingsnummer ;
47        onz-g:hasDataValue ?vestiging .
48    } UNION {
49        # Includeer ook de organisatie als geheel en label deze als vestiging
50        ?vestiging_uri onz-org:vestigingVan ?organisatie_uri .
51        BIND("Totaal organisatie" AS ?vestiging)
52    }
53
54    # Conditional binding voor unieke telling per type
55    BIND(IF(?type_overeenkomst = onz-pers:ArbeidsOvereenkomstBepaaldeTijd, ?overeenkomst, ?unbound) AS ?overeenkomst_bepaald)
56    BIND(IF(?type_overeenkomst = onz-pers:ArbeidsOvereenkomstOnbepaaldeTijd, ?overeenkomst, ?unbound) AS ?overeenkomst_onbepaald)
57}
58GROUP BY ?vestiging